TsSplitter batファイルモモチンのブログ/ウェブリブログ

TsSplitter batファイル

<< 作成日時： 2010/02/28 08:49 >>

ぬるま湯さんの記事を参考に、、、
D&DでTsSplitterを処理させるbatファイルを作った。

--------------------ここから---------------------

@echo off
rem このファイルにtsファイルをD&Dする。
rem 複数ファイルドロップ対応
rem SETにあるTsSplitterファイルへのパスを環境に合わせて変更しておくこと
rem TsSplitter用batファイル Version dori
rem 2010/02/25
rem
rem 処理内容
rem TsSplitter.exe でtsファイルからHDファイルを抜き出す。
rem
rem 番組開始EIT情報より前のデータは別ファイルになる。
rem 出力した.txtを.glに変更し編集アプリで直ぐに開けるようにする。
rem 都合の良いディレクトリに移動。
rem

SETLOCAL
SET SPath="C:\UserProgram\DTV\TsSplitter\TsSplitter.exe"
SET SParam1=-SD
SET SParam2=-1SEG
rem SET SParam3=-SEP3 ←バラつくので止める
SET SParam4=-OUT C:\Users\*****\TV\2_SPLIT_ts
SET SParam5=-GOP
SET SPath2=C:\Users\*****\TV\2_SPLIT_ts

@echo %DATE% %TIME% TsSplitterHD 処理開始

:start
IF "%~1"=="" GOTO syoriend
IF NOT "%~x1" == ".ts" GOTO next

:syori
%SPath% %SParam1% %SParam2% %SParam4% %SParam5% "%~1"
rem ↓.txtをglへ変更　HDのみ想定
cd %SPath2%
ren *.txt *.gl
rem ↓glファイルを移動
move /y *.gl C:\Users\****\TV\3_DEMUX_m2v
@echo %DATE% %TIME% 処理完了 "%~1"

:next
SHIFT
GOTO start

:syoriend
@echo %DATE% %TIME% TsSplitterHD 処理完了
rem ↓pause不要なら削除

ENDLOCAL

--------------------ここまで---------------------